Curso 2013-14. Estructuras de control condicionales con PSeInt

En ocasiones es necesario decidir cómo debe continuar un programa dependiendo del valor de alguna variable. Para controlar el camino a seguir se emplean dos estructuras principalmente: Si-Entonces y Según Hacer.

Para empezar vamos a tratar la estructura Si-Entonces.

Proceso Prg_4
    // Programa que pide un número por teclado y nos dice si es positivo o negativo
    Escribir "Programa que nos dice si un número tecleado es positivo o negativo"
    Escribir "Por favor, introduzca un número"
    Leer n
    Si n<0 Entonces
        Escribir "El número es negativo"
    Sino
        Escribir "El número es positivo"
    Fin Si
FinProceso

Ejercicio. Analiza el comportamiento del programa. Para ello, pulsa sobre el botón Dibujar diagrama de flujo... que está en la barra de herramientas superior.

Copia en tu cuaderno el diagrama de flujo.

Ejercicio. Modifica el programa para que la expresión lógica empleada como control del bloque Si-Entonces sea n>0.

Ejercicio. Escribe un programa que pida al usuario que teclee su edad. Compárala con la tuya y escribe en pantalla si la edad anotada es mayor o menor.

En matemáticas se considera al cero como un número que no es positivo ni negativo. El programa anterior no es capaz de responder correctamente si tecleamos el valor 0. Una forma de resolver este problema es anidando dos instrucciones Si-Entonces.

Proceso Prg_5
    // Programa que pide un número por teclado y nos dice si es positivo o negativo
    Escribir "Programa que nos dice si un número tecleado es positivo, negativo o cero"
    Escribir "Por favor, introduzca un número"
    Leer n
    Si n=0 Entonces
        Escribir "El número es cero"
    Sino
        Si n>0 Entonces
            Escribir "El número es positivo"
        Sino
            Escribir "El número es negativo"
        Fin Si
    Fin Si
FinProceso

Ejercicio. Copia en tu cuaderno el diagrama de flujo correspondiente a este programa. ¿Qué diferencias observas respecto al Programa 4?

La segunda estructura de control condicional que se puede usar con PSeInt es Según Hacer. Nos permite hacer elecciones múltiples. Veamos un ejemplo:

Proceso Prg_6
    // Programa que pide la calificación por teclado y nos dice su equivalente en letra
    Escribir "Programa que convierte una calificación numérica en letra"
    Escribir "Por favor, introduzca la calificación"
    Leer n
    Segun n Hacer
        0:
            Escribir "Insuficiente"
        1:
            Escribir "Insuficiente"
        2:
            Escribir "Insuficiente"
        3:
            Escribir "Insuficiente"
        4:
            Escribir "Insuficiente"
        5:
            Escribir "Suficiente"
        6:
            Escribir "Bien"
        7:
            Escribir "Notable"
        8:
            Escribir "Notable"
        De Otro Modo:
            Escribir "Sobresaliente"
        Fin Segun
FinProceso

La estructura Según Hacer inserta solo tres posibles opciones y la cuarta De Otro Modo, que es la que se escoge en caso de que ningún valor se ajuste a los que hemos anotado antes de cada signo ':'. En el ejemplo he insertado varias opciones más para conseguir todos los posibles valores.

Ejercicio. Comprueba que los mensajes se corresponden con los valores tecleados. Verifica que si pulsamos 9 o 10 nos aparece el mensaje "Sobresaliente". ¿Qué pasa si tecleo un número negativo o superior a 10?

Ejercicio. Corrige el programa para que solo muestre mensajes adecuados antes valores de calificación válidos. Si introducimos un valor que no esté comprendido entre 0 y 10 nos debe mostrar el mensaje "Calificación no válida".

Ejercicio. Escribe un programa que pida un número comprendido entre 1 y 7. Debe mostrar en pantalla el día de la semana asociado al número. Por ejemplo, si tecleo 1 debe escribir "Lunes".
Ejercicio. Aunque el esquema Según Hacer pone que espera recibir una variable numérica, también es posible teclear letras y otros caracteres. Escribe un programa que pida una letra y nos indique si es vocal o consonante. Debe mostrar en pantalla el mensaje adecuado. Por ejemplo, si tecleo "p" debe escribir "Consonante".